# Chapter 2: 游戏内外
define zhuchi = Character("主持人", color="#3c3fff", what_slow_cps=19, who_outlines=[(1, "#404040", 0, 0)])
define yang = Character("杨义涵", color="#ff3c3c", what_slow_cps=19, who_outlines=[(1, "#404040", 0, 0)])

label Chapter2_Scene1:
    $ game_day = 15
    $ game_period = "afternoon"

    scene bg classroom wide afterschool with fade
    play music "audio/XinLanDiary-Part1.ogg" fadein 2.0
    system_ "【Day 15·下午·七班教室】"

    show ryt dialogue normal at right with dissolve
    me "十一月的风从窗缝钻进来，带走了夏末最后的余热。我盯着手机屏幕上的推送——《四角州行动》校内赛，下周六。"
    me "从重点班跌到现在，好像已经很久了。但在游戏里，段位还是那个段位。至少这个，还没跌。"
    hide ryt with dissolve

    show xingyu at left with dissolve
    xingyu "涛哥！看公告没？校内赛！电竞社这次玩真的，冠军有机械键盘和——重点班旁听一周体验券！"
    hide xingyu with dissolve

    show ryt dialogue normal at right with dissolve
    me "……最后那个，是什么鬼奖励。"
    hide ryt with dissolve

    show lhy dialogue normal at left with dissolve
    lhy "从概率学角度，我们组队胜率取决于三个变量：枪法、战术配合、以及对手里有几个挂。"

    show xingyu at right with dissolve
    xingyu "小卡你也会玩？"
    hide xingyu with dissolve

    show lhy dialogue normal at left
    lhy "不怎么会。但我可以学。"
    hide lhy with dissolve

    show ryt dialogue normal at right with dissolve
    me "他这说话的表情，跟宣布今天要交数学作业时的一模一样。真是做啥事都认真。"
    me "我要邀请他吗？"

    menu:
        "邀请刘泓予":
            $ lhy_stats["affection"] += 5
            $ flag["lhy_team"] = True
            jump C2Side1
        "只找个游戏高手":
            $ xingyu_stats["affection"] -= 5
            $ flag["lhy_team"] = False
            jump C2S2
        "还没想好":
            $ flag["C2S1_think"] = False
            jump C2S2

label C2S2:
    $ game_day = 18
    $ game_period = "after_school"

    scene bg computer lab with fade
    play music "audio/XinLanDiary-Part1.ogg" fadein 2.0
    system_ "【Day 18·放学后·机房】"

    show ryt dialogue normal at right with dissolve
    me "训练赛，对手是颜涵和杨天赐。一个音游龙👃，一个不知道是男娘还是男同的玩意儿。胜率计算器直接报错。"
    hide ryt with dissolve

    show yh camerabag at left with dissolve
    yh "任懿涛。"
    yh "你是主突击位？"
    hide yh with dissolve

    show ryt dialogue normal at right with dissolve
    me "嗯，习惯了。"
    hide ryt with dissolve

    show yh camerabag at left with dissolve
    yh "那我针对你。"
    hide yh with dissolve

    show ryt dialogue normal at right with dissolve
    me "为啥？"
    hide ryt with dissolve

    show yh camerabag at left with dissolve
    yh "练习赛的意义就在于此。找到弱点。"
    yh "除非……你怕我？"
    # yh笑的立绘

    show ryt dialogue normal at right with dissolve
    me "他怎么又笑了！好瘆人……我好像更紧张了。"
    me "不过我才不会怕他呢"
    me "来啊。谁怕谁。"
    hide ryt with dissolve
    hide yh with dissolve

    stop music fadeout 1.0
    pause 1.0
    play music "audio/XinLanDiary-Part1.ogg" fadein 2.0

    system_ "【练习赛结束·2:2平】"

    show yh camerabag at left with dissolve
    yh "手速很快。但你的移动轨迹有pattern。每三次变向就有一次习惯性右偏。"
    hide yh with dissolve

    show ryt dialogue normal at right with dissolve
    me "……你连这个都记？"
    hide ryt with dissolve

    show yh camerabag at left with dissolve
    yh "习惯了。音游打多了，眼睛会自动追踪移动目标。"
    yh "对了。"
    yh "下周嘉年华筹备开始了。摄影社要做“莘澜面孔”影展。"
    yh "你会出镜的。"
    hide yh with dissolve

    show ryt dialogue normal at right with dissolve
    me "……凭什么？"
    hide ryt with dissolve

    show yh camerabag at left with dissolve
    yh "因为我会拍你。"
    yh "无论你同意与否。"
    hide yh with dissolve

    show ryt dialogue normal at right with dissolve
    me "他怎么刚说完就走。语气跟高一那回说”你今天发型更丑了“一模一样——不像威胁，倒是像通知。"
    hide ryt with dissolve

    # —— 机房门口 ——
    scene bg computer lab door with dissolve
    pause 0.5

    show xiaowei at right with dissolve
    me "林晓薇？你怎么在这？"

    xiaowei "欸——是不是打扰到你们了？"

    me "林晓薇......她怎么会出现在机房门口？这栋楼离文科班教室隔了一个操场。"

    show xiaowei embarrass at right with dissolve
    xiaowei "我、我是来还机房钥匙的！正好路过！"
    me "她耳朵红了。高一我就发现了，她说谎的时候先红耳朵。"

    show xiaowei at right with dissolve
    xiaowei "那、那个……比赛加油！我会去旁观的！"
    me "旁观？"
    xiaowei "啊不不是那个意思——就是——呃——友好支持！"
    hide xiaowei with dissolve

    me "她转身就跑。背影消失在楼梯拐角。"

    pause 0.5
    me "手机响了。"

    scene bg classroom phone closeup with dissolve
    system_ "【游戏内私聊】薇风拂晓：在吗？"

    me "又是她。每次都在我刚上线的时间出现。太巧了。"

    xiaowei_w "下周比赛，你会参加对吧？"
    me_w "你怎么知道？"
    xiaowei_w "……猜的。你游戏ID不是'逍遥剑客'吗，电竞社报名名单上有。"
    me_w "你还看报名名单？"
    xiaowei_w "随便看看！"
    xiaowei_w "那……比赛见。"
    me_w "等等，你到底哪个学校的？"

    system_ "【对方已离线】"

    me "又跑了。每次问到这个问题就消失。"
    me "但奇怪的是……我好像并没有很想知道答案。就这么聊着，也挺好。"

    $ xiaowei_stats["affection"] += 3
    $ xiaowei_stats["interactionFrequency"] += 2
    $ yh_stats["affection"] += 2
    $ yh_stats["understanding"] += 2

    if yutong_stats["affection"] >= 8 and yutong_stats["attention"] >= 12:   # 仅为符合格式规范，此jump必定执行
        jump C2S3

label C2S3:
    $ game_day = 20
    $ game_period = "afternoon"

    scene bg playground with fade
    play music "audio/XinLanDiary-Part1.ogg" fadein 2.0
    system_ "【Day 20·下午·操场旁】"

    show ryt dialogue normal at right with dissolve
    me "赛前最后一次训练。机房里设备嗡嗡响。"
    me "诶？门口什么时候站着个人。"
    hide ryt with dissolve

    show yutong at left with dissolve
    yutong "学习部检查。"
    yutong "学生会接到投诉，说电竞社训练影响晚自习秩序。"

    me "是苏雨桐。语气跟开会时一模一样。但她的眼睛在看我手机屏幕，不是看我。"

    me "我们只是利用课余时间——"

    yutong "《四角州行动》，是吗？"

    me "……你怎么知道游戏名？"

    yutong "资料调查。"
    yutong "……"
    yutong "手速确实很快。"

    me "她说这句话的时候，声音比刚才轻。然后推了推眼镜，像在掩饰什么。"

    yutong "但要小心重复性劳损。腕关节每天最好不要超过两万次点击。"

    me "……你在关心我？"

    yutong "这是学习部对参赛同学的健康提示。"
    yutong "另外……"
    yutong "重点班旁听体验券，是真的。"
    yutong "如果你想的话。"

    me "她转身走了。跟高一一样，走路很快，从不回头看。"
    me "但这句'如果你想的话'——她是在传达一个信息，还是在问一个问题？我分不清。"

    $ yutong_stats["affection"] += 2
    $ yutong_stats["attention"] += 2

    jump C2S4

label C2S4:
    $ game_day = 22
    $ game_period = "afternoon"

    scene bg auditorium with fade
    play music "audio/XinLanDiary-Part2.ogg" fadein 2.0
    system_ "【Day 22·周六·报告厅·电竞社校内赛】"

    if flag.get("competition_note"):
        show ryt dialogue normal at right with dissolve
        me "人比想象的多多了！后排都站满了。陈星宇在调试设备，刘泓予戴着耳机，腿上摊着笔记本。他真的记了笔记。"
        hide ryt with dissolve
    else:
        show ryt dialogue normal at right with dissolve
        me "人比想象的多多了！后排都站满了。陈星宇在调试设备，颜涵拿着他的D850相机。"
        hide ryt with dissolve

    show ryt dialogue normal at right with dissolve
    me "而我在找一个人。'薇风拂晓'说'比赛见'。如果她真的是本校的——"

    zhuchi "下面请最后一支签到队伍，'七星文学部'——呃，七班的队伍！"

    show xingyu at left with dissolve
    xingyu "走了涛哥！上场！"
    hide xingyu with dissolve
    hide ryt with dissolve

    pause 1.0
    system_ "【第一轮】胜"
    pause 0.5
    system_ "【第二轮】胜"
    pause 0.5
    system_ "【第三轮】平局"

    show ryt dialogue normal at right with dissolve
    me "手酸。苏雨桐说的两万次点击，可能快到了。"
    me "但更重要的是——观众席上，林晓薇正举着手机。目光对上的时候，她没有躲。她笑了，虎牙露出来。"
    hide ryt with dissolve

    scene bg classroom phone closeup with dissolve
    xiaowei_w "打得不错。"
    me_w "你在现场？"
    xiaowei_w "嗯。"
    me_w "哪里？"
    xiaowei_w "你猜。"

    scene bg auditorium with dissolve
    show ryt dialogue normal at right with dissolve
    me "我抬头扫了一圈。后排靠左，她戴着耳机，低头看手机。像是感应到什么，她忽然抬头——虎牙。"
    me "高一的时候，每次我讲完笑话，她都是第一个笑的那个。"
    hide ryt with dissolve

    $ xiaowei_stats["affection"] += 3
    $ xiaowei_stats["interactionFrequency"] += 2
    $ xiaowei_stats["is_xiaowei_w"] = True

    jump C2S5

label C2S5:
    # ######   CG     ######
    scene bg auditorium with dissolve

    zhuchi "那么，决赛即将开始——"

    yang "等一下！"

    show ryt dialogue normal at right with dissolve
    me "不好，是杨义涵！"
    hide ryt with dissolve

    yang "我有话要说！"
    yang "我要和任懿涛——"
    yang "生下一对冠军宝宝！！！"

    show ryt dialogue normal at right with dissolve
    me "他张开双臂。全场爆笑。主持人手里的麦克风差点掉了。刘泓予——刘泓予低着头，肩膀在抖。"
    me "连他都在笑。"
    hide ryt with dissolve

    menu:
        "……哈？":
            # depseek认为：事后杨义涵会主动找任懿涛聊天，触发关于"为什么要做夸张的事"的对话
            # （任懿涛发现杨义涵也有类似"用夸张掩饰什么"的一面）
            jump C2S5_end
        "你先找好对象再说。":
            $ yh_stats["affection"] += 1
            # ds说：杨义涵赛后会在群里发"任懿涛1:0我"，两人关系定位变成"损友"
            jump C2S5_end
        "推开他继续比赛":
            $ lhy_stats["affection"] += 1
            # 林晓薇在台下会小声说"好无情啊"然后偷笑
            jump C2S5_end

label C2S5_end:
    # ######   CG     ######
    # 存疑台词：
    # me "最终事件平息。比赛继续。但我鼻子里残留着韭菜盒子的味道，还有满场的笑声没散。"
    # me "这就是我的高二——不是在被人拍，就是在被人抱。"

    system_ "【决赛结果·七星文学部 2:1 获胜】"

    $ tao_stats["humorSense"] += 2

    jump C2S6

label C2S6:
    $ game_period = "evening"

    scene bg schoolgate evening with fade
    play music "audio/XinLanDiary-Part2.ogg" fadein 2.0
    system_ "【赛后·傍晚·校门口】"

    show ryt dialogue normal at right with dissolve
    me "散场的时候，我故意走慢了一点。陈星宇说去庆祝，刘泓予说有事，也走了。"
    me "我在等一个人。"
    hide ryt with dissolve

    show xiaowei at left with dissolve
    xiaowei "那个……"

    me "路灯下面，她的短发被风吹得有点乱。"

    me "你来了。"

    xiaowei "恭喜你。冠军。"
    xiaowei "我说了会旁观的嘛。"

    show ryt dialogue normal at right with dissolve
    me "我举起手机。屏幕上，是'薇风拂晓'的对话框。"
    me "但我问的不是比赛。"
    hide ryt with dissolve

    xiaowei "……"
    xiaowei "我就知道瞒不过你。"

    hide xiaowei with dissolve

    menu:
        "所以游戏里的配合，都是演的？":
            $ xiaowei_stats["affection"] += 1
            show xiaowei at left with dissolve
            xiaowei "不是演的！我真的觉得我们配合很好——啊不对，我不是那个意思——"
        "怎么不早说？":
            $ xiaowei_stats["affection"] += 2
            show xiaowei at left with dissolve
            xiaowei "因为怕你觉得奇怪……高一之后就分班了，突然游戏里相认什么的……"
        "……下次排位带带我？":
            $ xiaowei_stats["affection"] += 3
            show xiaowei at left with dissolve
            xiaowei "……欸？{cps=2}啊、好！{cps=20}不对，你段位比我高！"

    # 立绘：她低头绞着背包带子
    show xiaowei at left with dissolve
    xiaowei "总之……对不起？瞒了你这么久。"
    hide xiaowei with dissolve

    me "高一那个课间，她也是这样低头翻笔记，然后抬头说'你刚才那个笑话再讲一遍'。"

    me "没什么好道歉的。"
    me "只是下次要说实话。"
    me "在游戏里——如果有下次配合的话。"

    show xiaowei at left with dissolve
    xiaowei "……欸？"  # 懵，略微疑惑，少许惊喜
    xiaowei "一定！"  # 笑
    hide xiaowei with dissolve

    me "她笑了。虎牙露出来。跟高一那个课间一样的笑。"

    $ xiaowei_stats["synergy"] += 3
    $ xiaowei_stats["interactionFrequency"] += 2

    jump C2S7

label C2S7:
    $ game_period = "night"

    scene bg ryt room night with fade
    stop music fadeout 1.0
    play music "audio/XinLanDiary-Part2.ogg" fadein 2.0
    system_ "【同夜·家中】"

    show ryt dialogue normal at right with dissolve
    me "躺在床上，盯着天花板。今天发生了太多事——冠军、拥抱、她身份的揭晓。"
    me "手机亮了。"
    hide ryt with dissolve

    yutong "《四角州行动》概率计算题，我出在了学习部的下周挑战里。如果你有兴趣的话。"

    me "她怎么有我的联系方式。"
    me "不对，她是学习部部长，找谁的联系方式都行。但为什么专门发给我？"
    me "概率计算题。用游戏出题。跟上次嘉年华数学摊位那个一样——她知道我会感兴趣。"

    system_ "【画廊更新】电竞时刻：手速与反应速度的实证研究。"

    me "果然。李泽瑄不会放过任何素材。"
    me "但照片里——不止我一个人。陈星宇在画面边缘大笑，刘泓予低头记笔记，林晓薇在观众席举起手机。还有角落里，苏雨桐抱着笔记本，假装在看别的地方。"
    me "原来被拍下来的时候，我一直不是一个人。"
    me "窗外，十一月的夜空很干净。高一的时候我从没注意过这些。现在我开始观察。"

    $ yutong_stats["affection"] += 2
    $ yutong_stats["attention"] += 2
    $ lzx_stats["infoOpenness"] += 1
    $ tao_stats["selfAcceptance"] += 2

    pause 1.0
    scene bg black with fade
    pause 1.5
    system_ "【第二章·游戏内外·完】"

    return