XinLanDiary/game/Chapters/Chapter1.rpy

# Chapter 1: 画廊风波
# Characters defined here that are not in script.rpy


label Chapter1_Scene1:
    $ game_day = 1
    $ game_period = "morning"

    scene bg classroom featryt with fade
    system_ "【Day 1·上午·七班教室】"

    me "{cps=25}九月的风还带着夏末的燥热，那道斜切过窗台的阳光，在黑板上画出一道明晃晃的线。\n就像我的人生，被分成了两半——线的那头，是重点班；线的这头，是我。"
    me "这道光就这么直直地切过来，像是在提醒我，你就在这儿，也只能在这儿了。\n曾经唾手可得，如今遥不可及。"

    pause 0.5

    show xingyu thinking at left
    xingyu "涛哥，你咋又对着黑板发呆？"
    play music "audio/XinLanDiary-Part1.ogg" fadein 0.5
    show xingyu laughing
    xingyu "该不会是在研究光线折射角度吧？"
    hide xingyu

    show ryt dialogue normal at right
    me "{cps=28}错！{cps=1} {cps=17}我在思考一个深刻的哲学问题 ——{cps=5} {cps=18}为什么物理老师的头发总是逆着地心引力生长？"
    hide ryt

    show lhy dialogue normal at left
    lhy "根据观察，王老师的发际线在过去六个月里上移了0.8厘米，主要集中于期中考试前后。\n相关性系数0.76。"

    show ryt hit at right
    me "你们看！{cps=6} {cps=20}这就是重点班的余孽，看什么都得用数据说话。吃我一掌！"

    show lhy dialogue normal at left, shake_rotate
    lhy "你的发力角度今天调整了，从之前的斜上45度改为42度，动能转化效率提升了约5\%。有进步。"
    hide lhy
    show lhy dialogue normal at left
    show ryt dialogue embarrass pocket at right

    show xingyu laughing big
    xingyu "{cps=5}哈哈哈哈哈{cps=15}！\n真是一对苦命鸳鸯！"

    $ game_period = "after_school"
    stop music fadeout 1.0
    play sound "audio/AfterClassRing.ogg" noloop
    queue sound "audio/MainMenu.ogg" fadein 1.0
    scene bg black with fade
    pause 1.0
    scene bg playground twilight

    show xingyu laughing 2
    xingyu "终于放学了！\n操场！走，三对三！今天必须把九班那群人打趴下！"
    hide xingyu
    mom "「17:40校门口便利店，别迟到。」"
    show ryt dialogue normal at right
    me "......妈妈又给我发这消息"
    me "我得等车。\n你们先打，下次我一定来 {cps=3} {cps=20}——前提是我妈能接受她儿子在篮球场上挥洒青春而不是在车里背单词。"
    show xingyu at left
    xingyu "涛哥，你这样不行啊，迟早得「起义」。"
    stop sound fadeout 1.0

    hide xingyu with dissolve
    play music "audio/MainMenu.ogg" fadein 1.0

    me "那声'起义'在心里荡开了一个小涟漪。"
    me "他说得对——但说出口的代价，比他想的要重得多。"
    hide ryt with dissolve

    pause 0.8

    # 草稿原文：「教室里人快走空时，手机震动了」——切回空教室背景
    scene bg classroom wide afterschool with dissolve

    lzx "画廊更新了，有惊喜。友情提示：这次可能会火。"

    me "……“任懿涛观察日志？”"
    system_ "【画廊更新】力学之美：作用力与反作用力在友谊中的应用。\n图注：请注意研究对象在空中时的肢体协调度与落地后的平衡恢复能力。"
    #system_ "图注：请注意研究对象在空中时的肢体协调度与落地后的平衡恢复能力。"

    show ryt dialogue embarrass pocket at center with dissolve
    me "三张连拍……全程记录，还加了学术注释。行吧，就是个玩笑。"
    hide ryt with dissolve
    stop music fadeout 1.0

    $ lhy_stats["affection"] += 3
    $ lhy_stats["trust"] += 2
    $ xingyu_stats["affection"] += 3
    $ xingyu_stats["cooperation"] += 2
    $ tao_stats["humorSense"] += 2
    $ lzx_stats["infoOpenness"] += 1

    jump Chapter1_Scene2

label Chapter1_Scene2:
    $ game_day = 2
    $ game_period = "morning"
    scene bg classroom morning featryt with fade
    play music "audio/XinLanDiary-Part1.ogg" fadein 2
    system_ "【Day 2·早自习前·七班教室】"

    me "第二天早上，一切都不一样了。"
    me "刚踏进七班，就感觉空气里有种微妙的兴奋。"
    me "几个别班男生挤在后门，看到我进来——"
    tongxue "涛哥！高手啊！"
    tongxue "这弹跳力，不考虑加入校篮球队？"
    tongxue "刘泓予还好吗？需要验伤不？"

    show ryt dialogue normal at c1s2_ryt_pos with dissolve
    me "笑，我只管笑。"
    hide ryt with dissolve

    me "走到座位，拿出手机——"
    system_ "【匿名论坛·置顶】震惊！高二学霸竟在教室对同学实施「物理攻击」！\n 回复：502层 | 转发：88"

    show ryt dialogue embarrass pocket at c1s2_ryt_pos with dissolve
    me "……五百多层？"
    me "李泽瑄那个链接，被人转到论坛上了？！"
    hide ryt with dissolve

    scene bg playground morning aerial with fade
    me "课间操，成了公开处刑。"
    me "站在队列里，我能感觉到四面八方投来的目光，听到各处的窃窃私语。"


    #show ryt hit at center with dissolve
    scene bg playground with dissolve
    me "深吸一口气——经过八班队列时，我故意做了个跳起来打空气的动作，表情夸张。"
    hide ryt with dissolve
    tongxue "哈哈哈哈——"
    stop music fadeout 1.0
    me "果然，又是一阵笑声。"
    me "我的那层盔甲还在。   对吗？"

    pause 0.3

    # 关键场景：刘泓予看穿
    play music "audio/MainMenu.ogg" fadein 2.0
    show lhy dialogue normal at right with dissolve
    lhy "你刚才那个假动作，面部肌肉的紧张程度是平时的1.3倍。"
    show ryt dialogue embarrass pocket at left with dissolve
    me "……"
    lhy "高强度社交应激状态下，人体会产生应激性微表情抑制行为。你的眼轮匝肌收缩时序比平时延迟了0.2秒。"

    hide ryt with dissolve
    hide lhy with dissolve

    me "他说这话的时候，语气跟讲公式一模一样。"
    me "但不知道为什么，被他这么一说……我反而松了口气。"
    me "有人看见了，但没有嘲笑。只是……记录。"

    #stop music fadeout 1.0

    $ lhy_stats["affection"] += 5
    $ lhy_stats["trust"] += 5
    $ lhy_stats["empathy"] += 3
    $ tao_stats["selfAcceptance"] += 1
    $ tao_stats["studyStress"] += 2

    jump Chapter1_Scene3

label Chapter1_Scene3:
    # —— 视角A：苏雨桐·学生会会议室 ——
    $ game_period = "afternoon"
    scene bg meetingroom meeting with fade
    "{cps=20}【同日下午·学生会会议室】"  # system_ "【同日下午·学生会会议室】"

    me "下午的学生会会议室里，宣传部的干事滔滔不绝。"
    ganshi "——就像最近论坛里很火的那个'力学之美'系列，这种原生内容特别容易引发共鸣，我们宣传部可以朝这个方向多发掘——"

    pause 0.3
    scene bg meetingroom featlxw at zoom_to_upper_right
    yutong "稍等。"
    pause 0.5
    yutong "这类内容涉及肖像权问题。根据《民法典》第一千零一十九条，未经同意使用他人肖像，即便没有营利目的，如果造成当事人困扰，也涉嫌侵权。"
    yutong "尤其是这种可能引发负面关注的传播，我们需要更谨慎。"

    me "会议室陷入短暂沉默。" # 把me删掉？ 不删！.lzx

    scene bg meetingroom meeting with dissolve
    ganshi "雨桐提醒得对……这个问题我们后续会注意的。那继续下一项——"

    "{cps=20}会议继续。没人看见，她放在桌下的手机屏幕上——" # 这个me也删掉？删掉！.lzx
    system_ "【苏雨桐手机·加密相册·新增1张】"
    yutong "……力学之美……有趣的视角。"
    "{cps=20}她把第三张连拍放大，看了很久。"
    "{cps=20}那个落地踉跄、表情错愕的瞬间，和高一时那个数学竞赛获奖后，在走廊里短暂发呆的男生，微妙地重合了。"
    yutong "「给岁月以文明，而不是给文明以岁月。」"
    yutong "我那天递给他的纸条上可不仅写了“恭喜”二字……"
    yutong "这句话，他没有回应。\n 或许他根本就没有看见……"

    stop music fadeout 1.0

    $ yutong_stats["affection"] += 3
    $ yutong_stats["attention"] += 5
    $ yutong_stats["h_academicSupport"] += 1

    pause 0.5

    # —— 视角B：林晓薇·高二一班走廊 ——
    play music "audio/XinLanDiary-Part1.ogg" fadein 2.0
    scene bg corridor with dissolve
    "【同日下午·高二一班走廊】"

    show xiaowei at left with dissolve
    "同一时间，另一个人也在看那张照片。"
    tongxue "晓薇你快看！这不是你们一班那个任懿涛吗？他怎么还是这么搞笑！"
    xiaowei "拍得好生动啊！你们说，要是我也这样跳起来打人，会不会也这么有效果？"
    tongxue "哈哈哈哈！"
    hide xiaowei with dissolve
    stop music fadeout 1.0

    "{cps=20}她笑着，眼睛却没有离开屏幕。"
    "{cps=20}那种真实的活力，让她觉得……在礼貌而疏离的文科班里，有什么东西被触动了。"

    #system_ "【切换账号：薇风拂晓】"
    play music "audio/XinLanDiary-Part1.ogg" fadein 2.0
    scene bg classroom phone closeup with dissolve
    system_ "好友列表：逍遥剑客 [[在线]"
    xiaowei_w "在吗？问个事。你们学校是不是有个挺搞笑的人？最近好像因为什么照片火了。"
    "发出去的瞬间她就后悔了。太突兀了——但已经来不及撤回。"
    pause 0.8
    me_w "？？？你哪个学校的？"
    xiaowei_w "就随便问问，不想说算了。"
    me "她收起手机。上课铃响了。"
    me "路过七班门口时，她下意识往里看了一眼——"
    show ryt dialogue normal at right with dissolve
    show xingyu at left with dissolve
    me "任懿涛正背对门口，和陈星宇比划着什么。大概又是游戏攻略。"
    hide ryt with dissolve
    hide xingyu with dissolve
    stop music fadeout 1.0

    $ xiaowei_stats["affection"] += 4
    $ xiaowei_stats["interactionFrequency"] += 2
    $ xiaowei_stats["is_xiaowei_w"] = False

    jump Chapter1_Scene4

label Chapter1_Scene4:
    $ game_period = "after_school"
    $ gallery_photo4_unlocked = True
    play music "audio/MainMenu.ogg" fadein 2.0
    scene bg classroom wide afterschool with fade
    "{cps=20}【同日放学后·七班教室】"    # system_ "【同日放学后·七班教室】"

    show ryt dialogue normal at right with dissolve
    me "放学了。教室里还剩几个人。"
    me "'薇风拂晓'……你哪个学校的？"
    me "这个账号……我好像只在游戏里见过。"

    show xingyu at left with dissolve
    xingyu "涛哥，你咋了？还在想那个破照片的事？"
    me "我在思考更严肃的问题——为什么总有人对我的英姿如此念念不忘？"
    me "我来看看画廊的统计数据，\n论坛转发之后，访问量肯定不少——就当看个热闹。"

    hide ryt with dissolve
    system_ "【画廊后台·访问统计】今日新增：347次 | 来源：匿名论坛转发"

    show ryt dialogue normal at right with dissolve
    me "果然，三百多。论坛一转，全涌进来了。"
    me "不过……"
    me "我往下翻，手指停在了一条记录上。"
    hide ryt with dissolve

    system_ "固定IP · 实验楼三层 · 每隔2-3天 · 晚9-10点"
    system_ "最早记录：高一上学期（画廊建立初期）"

    show ryt dialogue embarrass pocket at right with dissolve
    me "……等等。这个IP，从高一就开始了？"
    me "星宇，实验楼三层的网络，是不是只有13班和实验室在用？"
    xingyu "哟，有人盯上你了啊。对，那个段就是13班和几个竞赛实验室专用。"
    xingyu "怎么，涛哥的英姿连重点班都征服了？"
    hide xingyu with dissolve
    show ryt dialogue embarrass pocket2 at right with dissolve

    me "13班。那个我刚离开的世界。"
    me "……是谁？"

    pause 0.5
    hide ryt with dissolve

    # 反侦察行动
    play music "audio/XinLanDiary-Part1.ogg" fadein 2.0
    show xingyu at left with dissolve
    xingyu "各位！我有个绝妙的主意——"
    xingyu "既然那个画廊这么喜欢拍涛哥，咱们不如搞个「反侦察行动」！"
    xingyu "找出那个偷拍者，然后拍他的黑历史！怎么样？"

    show lhy dialogue normal with dissolve
    lhy "理论上可行，但需要注意几个问题：\n第一，如何确定拍摄者会再次行动；\n第二，如何在保护自身隐私的前提下进行反追踪；\n第三——"
    xingyu "哎呀小卡你别扫兴！就是玩嘛！涛哥，你说干不干？"
    hide lhy with dissolve

    stop music fadeout 0.8
    show ryt dialogue normal at right with dissolve
    me "看着眼前这群人。认识不过一个多月——但他们就这么凑过来，商量这种无聊又有趣的计划。"
    me "在重点班时，从来没有过这样的时刻。"

    play music "audio/XinLanDiary-Part1.ogg" fadein 1.0
    me "行啊！但咱们得专业！要有分工！有排班表！有应急预案！还要有——"
    hide ryt with dissolve
    hide xingyu with dissolve
    pause 0.4

    # 颜涵出场
    show yh camerabag at left with dissolve
    yh "要有旁观席位。"
    #me "声音从后门传来。颜涵，拎着相机包，表情平静。"
    yh "我负责记录你们的失败过程。"
    hide yh with dissolve
    tongxue "哈哈哈哈哈！"
    stop music fadeout 1.0

    show ryt dialogue normal at right with dissolve
    me "我也跟着笑。但眼睛不自觉地望向窗外。"
    me "夕阳下的实验楼泛着暖黄的光，三楼东侧的窗户反射着落日的余晖。"
    me "那里有谁，在看着我？"
    me "还有那个'薇风拂晓'，到底是谁？"
    hide ryt with dissolve

    $ xingyu_stats["affection"] += 5
    $ xingyu_stats["cooperation"] += 5
    $ xingyu_stats["helpfulness"] += 3
    $ lhy_stats["affection"] += 3
    $ yh_stats["affection"] += 3
    $ yh_stats["understanding"] += 2
    $ tao_stats["selfAcceptance"] += 2

    pause 0.5

    # 便利店
    $ game_period = "evening"
    play music "audio/XinLanDiary-Part2.ogg" fadein 2.0
    scene bg convenience store with fade
    system_ "【傍晚17:25·校门外便利店】"

    show ryt normal spec at c1s4_ryt_pos with dissolve
    me "17:25，准时出现在校门外三百米处的便利店。"
    me "买瓶饮料，站在店门口等车，看着其他学生自由地走过。"
    me "骑车的，步行的，三五成群说笑的。每个人脸上都有种松弛感。"
    #hide ryt with dissolve

    show aunt normal at left with dissolve
    "便利店主" "小任，新品。尝尝，你们年轻人喜欢这个。"
    #show ryt dialogue normal at right with dissolve
    me "谢了阿姨。"
    hide ryt with dissolve
    hide aunt with dissolve

    me "拧开那瓶柚子味气泡水，靠在栏杆上。"
    pause 0.6

    # 苏雨桐骑车经过——本章关键镜头
    scene bg schoolgate featsyt with dissolve
    me "那是 ——{cps=1} {cps=20}苏雨桐"
    me "她推着自行车从校门口出来。车篮里放着一本厚厚的书。"
    me "她停在路口等红灯，低头看了眼手机——"
    me "然后嘴角很轻地抬了一下。几乎算不上笑，只是一个微小的弧度。"
    scene bg convenience store with dissolve
    show ryt normal spec at c1s4_ryt_pos with dissolve
    show ryt normal spec at slide_right(distance=200, duration=0.5) with dissolve
    me "我下意识往便利店的阴影里退了半步。"
    hide ryt with dissolve
    scene bg sunset featsyt with dissolve
    me "绿灯。她跨上车，黑发在傍晚的风里扬起，朝着与我家相反的方向骑远了。"

    scene bg convenience store with dissolve
    pause 0.5
    me "自由。"
    me "这个词突然撞进脑子里——不是解题时的快感，而是一种更基础的东西：掌控自己轨迹的权利。"

    mom "「到了。」"
    show ryt dialogue normal at right with dissolve
    me "挺好的。特别开心。"
    hide ryt with dissolve
    me "……我说出这句话的时候，语气轻松得像是真的。"
    me "车驶入车流。靠在车窗上，看着外面倒退的街景。"

    $ yutong_stats["affection"] += 2
    $ yutong_stats["attention"] += 3
    $ tao_stats["selfAcceptance"] += 1
    $ tao_stats["studyStress"] += 1

    pause 0.5

    # 双视角结尾
    $ game_period = "night"
    scene bg black with fade
    system_ "【同夜·城市另一头】"

    me "城市的另一头，苏雨桐刚回到家。"
    yutong "TaoliTaoli……今天依然没有更新。"
    system_ "【任懿涛画廊·访问计数器：+1】"
    me "她一张张翻看那些照片。相册里已经积累了二十几张，按时间顺序排列。"
    yutong "……在这个高度秩序化的生活里，观察一个如此不协调、如此鲜活的存在……有种奇妙的慰藉。"

    $ yutong_stats["affection"] += 3
    $ yutong_stats["attention"] += 4

    pause 0.5
    system_ "【几公里外·林晓薇的房间】"
    me "几公里外，林晓薇躺在床上，盯着天花板发呆。"
    me_w "你问的那个人，确实是我们学校的。怎么，你认识？"
    me "那条回复躺在对话框里，她还没想好怎么回。"
    me "她翻看相册，看着任懿涛在空中那个狰狞又认真的表情，看着落地时那个措手不及的踉跄。"
    me "然后，她做了个决定。"
    xiaowei "明天，课间的时候，以真实身份去七班找他。"
    xiaowei "就说：那张照片拍得真好，特别生动。"
    xiaowei "……就想看看，他会是什么反应。"

    $ xiaowei_stats["affection"] += 3
    $ xiaowei_stats["interactionFrequency"] += 3

    pause 0.5

    # 章节尾声
    scene bg black with fade
    me "窗外，九月的夜晚渐渐深了。城市灯火一盏盏亮起，每扇窗户后都是一个正在展开的故事。"
    me "任懿涛的故事，在这一天，因为几张滑稽的照片，悄悄拐上了一条他自己都未曾预料的道路。"
    me "这条路上，已经有两位女生在等着他——"
    me "一个在暗处静静观察，一个在明处准备靠近。"
    pause 1.0
    me "而他自己，还不知道。"
    pause 1.5
    system_ "【第一章·画廊风波·完】"

    return